Private WithEvents Items As Outlook.Items

Private Sub Application_Startup()
  ' Verweis auf die Elemente des zu überwachenden
  ' Ordners.
  Set Items = Application.GetNamespace("MAPI") _
    .GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub Items_ItemAdd(ByVal Item As Object)
  ' Aufruf, wenn ein Element dem überwachten Ordner
  ' hinzugefügt wird.
  If TypeOf Item Is Outlook.MailItem Then
    AddSenderEmailAddress Item
  End If
End Sub

Private Sub AddSenderEmailAddress(Mail As Outlook.MailItem)
  ' Fügt der Mail ein benutzerdefiniertes Feld hinzu
  ' und schreibt die Absenderadresse hinein.
  On Error Resume Next
  Dim rdItem As Object
  Dim Field As Outlook.UserProperty

  ' SafeMailItem für Outlook.MailItem erstellen
  Set rdItem = CreateSafeItem(Mail)

  ' Wenn das benutzerdefinierte Feld nicht existiert,
  ' dann erstellen.
  Set Field = Mail.UserProperties("SenderAddress")
  If Field Is Nothing Then
    Set Field = Mail.UserProperties.Add("SenderAddress", olText, True)
  End If

  ' Absenderadresse im benutzerdefinierten Feld speichern.
  Field.Value = rdItem.SenderEmailAddress
  Mail.Save

  ' Redemption-Objekt freigeben. Dieser Aufruf muss(!) immer
  ' durchgeführt werden. Durch eine entsprechende
  ' Fehlerbehandlungsroutine muss das gewährleistet werden!
  ReleaseSafeItem rdItem
End Sub