VBOffice

Regeln jetzt anwenden

Regeln können manuell gestartet werden, aber das erfordert sehr viele Klicks. Nutzen Sie dieses Makro, um alle Regeln mit Ihren gewünschten Einstellungen auszuführen.

Zuletzt geändert: 07.05.2015 | Aufrufe: 18.907  | #146
◀ Vorheriges Beispiel Nächstes Beispiel ▶
ReplyAll ReplyAll
Mit diesem Addin für Outlook erhalten Sie in verschiedenen Situationen eine Warnung, bevor Sie auf eine Email versehentlich allen anderen Empfängern antworten.

In der folgenden, ersten Funktion des Makros legen Sie Ihre gewünschten Einstellungen fest.

  • RunEnabledRules: True bedeutet, dass die aktivierten Regeln ausgeführt werden sollen. Setzen Sie den Wert auf False, dann werden diese ignoriert.
  • RunDisabledRules: False bedeutet, dass die deaktivierten Regeln ignoriert werden sollen. Setzen Sie den Wert auf True, dann werden die deaktivierten Regeln auch ausgeführt.
  • ExecuteOption: Mit den Werten 0, 1 oder 2 legen Sie fest, ob die Regeln auf alle, nur auf gelesene oder nur auf ungelesene Nachrichten angewendet werden sollen.
  • Inbox: True bedeutet, dass die Regeln auf den Posteingang (und ggf. dessen Unterordner) ausgeführt werden. Setzen Sie den Wert auf False, dann wird statt des Posteingangs der aktuelle Ordner zum Startordner.
  • IncludeSubfolders: True bedeutet, dass die Regeln auf den Startordner und alle seine Unterordner angewendet werden. Setzen Sie den Wert auf False, wenn die Regeln nur auf den Startordner angewendet werden sollen.

Starten Sie das Makro z.B. über ALT+F8.


tip  So fügen Sie Makros in Outlook ein
Public Sub RunRules()
  Dim RunEnabledRules As Boolean
  Dim RunDisabledRules As Boolean
  Dim ExecuteOption As Long
  Dim IncludeSubfolders As Boolean
  Dim Inbox As Boolean
  
  'Aktivierte Regeln ausführen (true/false)
  RunEnabledRules = True
  
  'Deaktivierte Regeln ausführen (true/false)
  RunDisabledRules = False
  
  'Auf welche Nachrichten sollen die Regeln angewendet werden?
  '0 = alle Nachrichten
  '1 = nur gelesene Nachrichten
  '2 = nur ungelesene Nachrichten
  ExecuteOption = 0
  
  'Startordner ist der Posteingang (true) oder der aktuelle Ordner (false)
  Inbox = True
  
  'Regeln nur auf den Startordner anwenden (false) oder auch auf dessen Unterordner (true)
  IncludeSubfolders = False
  
  RunRules_ex RunEnabledRules, RunDisabledRules, ExecuteOption, IncludeSubfolders, Inbox
End Sub
SAM SAM
Legen Sie fest, mit welcher "Identität" Ihre Emails beim Empfänger erscheinen sollen. Mit SAM bestimmen Sie den Absender und Speicherort für Emails anhand von Regeln.

Dieser zweite Teil führt die eigentliche Arbeit aus. Hier brauchen Sie nichts anzupassen.

Private Sub RunRules_ex(ByVal RunEnabledRules As Boolean, ByVal RunDisabledRules As Boolean, _
  ByVal ExecuteOption As Long, ByVal IncludeSubfolders As Boolean, ByVal Inbox As Boolean)
  Dim Store As Outlook.Store
  Dim Rules As Outlook.Rules
  Dim Rule As Outlook.Rule
  Dim Folder As Outlook.Folder
  
  If Inbox Then
    Set Folder = Application.Session.GetDefaultFolder(olFolderInbox)
  Else
    Set Folder = Application.ActiveExplorer.CurrentFolder
  End If
  
  Set Store = Application.Session.DefaultStore
  Set Rules = Store.GetRules
  For Each Rule In Rules
    If Rule.RuleType = olRuleReceive Then
      If Rule.Enabled Then
        If RunEnabledRules Then
          Rule.Execute , Folder, IncludeSubfolders, ExecuteOption
        End If
      Else
        If RunDisabledRules Then
          Rule.Execute , Folder, IncludeSubfolders, ExecuteOption
        End If
      End If
    End If
  Next
End Sub
Category-Manager Category-Manager
Mit dem Category-Manager können Sie Outlook Kategorien gruppieren, synchronisieren und filtern, neuen Emails automatisch die Kategorie des Absenders zuweisen und vieles mehr. Das Addin ist auch für IMAP geeignet.
email  Senden Sie eine Nachricht