VBOffice

Nachverfolgungs-Flag von Email löschen

Mit VBA können Sie die Kennzeichnung zur Nachverfolgung komplett entfernen, sobald die Aufgabe erledigt ist.

Zuletzt geändert: 15.03.2007 | Aufrufe: 23.863  | #46
◀ Vorheriges Beispiel Nächstes Beispiel ▶
Reporter Reporter
Mit dem Reporter erstellen Sie Berichte für Ihre Outlook Daten. Mit wenigen Klicks werden Werte aus Aufgaben, Terminen und dem Journal summiert.

Üblicherweise werden erledigte Emails durchgestrichen dargestellt. Diese Skript dagegen löscht das Nachverfolgungsflag komplett, wenn Sie eine Email als 'Erledigt' markieren.


tip  So fügen Sie Makros in Outlook ein
Private WithEvents m_Explorer As Outlook.Explorer
Private WithEvents m_Mail As Outlook.MailItem
Private m_IgnoreEvent As Boolean

Private Sub Application_Startup()
  Set m_Explorer = Application.ActiveExplorer
End Sub

Private Sub m_Explorer_SelectionChange()
  Dim obj As Object
  Dim Sel As Outlook.Selection

  Set m_Mail = Nothing

  Set Sel = m_Explorer.Selection
  If Sel.Count Then
    Set obj = Sel(1)
    If TypeOf obj Is Outlook.MailItem Then
      Set m_Mail = obj
    End If
  End If
End Sub

Private Sub m_Mail_PropertyChange(ByVal Name As String)
  On Error Resume Next

  If m_IgnoreEvent = False Then
    If Name = "FlagStatus" Then
      If m_Mail.FlagStatus = olFlagComplete Then
        m_IgnoreEvent = True
        m_Mail.FlagStatus = olNoFlag
        m_Mail.Save
        m_IgnoreEvent = False
      End If
    End If
  End If
End Sub
Category-Manager Category-Manager
Mit dem Category-Manager erhalten Sie blitzschnellen Zugriff auf die Hauptkategorienliste in Microsoft Outlook, verwalten diese und können Ihre Farbkategorien auf mehreren Computern nutzen.
email  Senden Sie eine Nachricht