VBOffice

Kalender archivieren

So bauen Sie eine eigene Auto-Archivierung für Ihre Outlook-Ordner.

Zuletzt geändert: 07.02.2007 | Aufrufe: 53.314  | #43
◀ Vorheriges Beispiel Nächstes Beispiel ▶
OLKeeper OLKeeper
Der OLKeeper verhindert zuverlässig, dass Sie Microsoft Outlook unbeabsichtigt schließen und so etwa wichtige Emails verpassen würden.

Über Ordnereigenschaften können Sie festlegen, ob und in welchen Intervallen ein Ordner archiviert werden soll. Wer Spaß daran hat, kann das aber natürlich auch per Code selbst machen. Dieses Beispiel archiviert alle Einträge des Standardkalenders, deren Ende ein gewisses Alter erreicht haben, in einen zu wählenden Ordner.


tip  So fügen Sie Makros in Outlook ein
Public Sub ArchivItems()
  Dim SrcFolder As Outlook.MAPIFolder
  Dim DestFolder As Outlook.MAPIFolder
  Dim Items As Outlook.Items
  Dim obj As Object
  Dim Appt As Outlook.AppointmentItem
  Dim Ns As Outlook.NameSpace
  Dim DueDate As Date
  Dim i&
  Dim Counter&

  Set Ns = Application.GetNamespace("MAPI")

  'Archivordner wählen
  Set DestFolder = Ns.PickFolder
  If DestFolder Is Nothing Then Exit Sub

  'Altersgrenze festlegen: Archivieren, wenn älter als 7 Tage
  DueDate = DateAdd("d", -7, Now)

  'Standardkalender archivieren
  Set SrcFolder = Ns.GetDefaultFolder(olFolderCalendar)
  Set Items = SrcFolder.Items

  For i = Items.Count To 1 Step -1
    Set obj = Items(i)
    If TypeOf obj Is Outlook.AppointmentItem Then
      Set Appt = obj
      If DateDiff("s", Appt.End, DueDate, vbUseSystemDayOfWeek, vbUseSystem) > 0 Then
        Appt.Move DestFolder
        Counter = Counter + 1
      End If
    End If
  Next

  MsgBox "Es wurde(n) " & Counter & " Element(e) verschoben.", vbInformation
End Sub
Category-Manager Category-Manager
Mit dem Category-Manager können Sie Outlook Kategorien gruppieren, synchronisieren und filtern, neuen Emails automatisch die Kategorie des Absenders zuweisen und vieles mehr. Das Addin ist auch für IMAP geeignet.
email  Senden Sie eine Nachricht