VBOffice

Freie Kategorieeingabe

Dieses Makro ermöglicht es Ihnen, Emails (und andere Elemente) mit beliebigen Stichwörtern zu versehen, ohne dass Sie diese erst in der Hauptkategorienliste anlegen müssen.

Zuletzt geändert: 15.12.2009 | Aufrufe: 30.048  | #80
◀ Vorheriges Beispiel Nächstes Beispiel ▶
Category-Manager Category-Manager
Mit dem Category-Manager können Sie Outlook Kategorien gruppieren, synchronisieren und filtern, neuen Emails automatisch die Kategorie des Absenders zuweisen und vieles mehr. Das Addin ist auch für IMAP geeignet.

Bis Outlook 2003 konnte jedem Element eine Kategorie (ein Stichwort) direkt hinzugefügt werden, ohne dass dieses zuvor in der Hauptkategorienliste angelegt werden mußte. Seit Outlook 2007 geht das nicht mehr.

Mit der folgenden Funktion können Sie über einen Eingabedialog wieder direkt Stichworte vergeben. Mehrere Begriffe können mit einem Komma oder Semikolon getrennt eingegeben werden.

Kopieren Sie die Funktion in das Modul "DieseOutlookSitzung" und speichern Sie das Projekt. Danach können Sie in Outlook eine Schaltfläche zum Aufruf der Funktion erstellen, indem Sie mit rechts auf eine Symbolleiste klicken, dann auf Anpassen, Befehle, Makros und den Funktionsnamen auf die Symbolleiste ziehen. Mit einem weiteren Rechtsklick auf den neu erstellten Button können Sie dessen Aussehen verändern. (Führen Sie diese Schritte einmal für einen beliebigen Ordner aus und bei Bedarf einmal für jedes Formular, in dem die Funktion auch zur Verfügung stehlen soll.)

Sie können die Funktion auch einfach über alt+f8 aufrufen.


tip  So fügen Sie Makros in Outlook ein
Public Sub EnterKeyword()
  Dim Coll As VBA.Collection
  Dim obj As Object
  Dim s$

  Set Coll = GetCurrentItems
  If Coll.Count = 0 Then Exit Sub

  s = InputBox("Keyword:")
  s = Trim$(s)
  If Len(s) = 0 Then Exit Sub

  For Each obj In Coll
    obj.Categories = obj.Categories & "," & s
    obj.save
  Next
End Sub

Private Function GetCurrentItems() As VBA.Collection
  Dim Coll As VBA.Collection
  Dim Win As Object
  Dim Sel As Outlook.Selection
  Dim obj As Object
  Dim i&

  Set Coll = New VBA.Collection
  Set Win = Application.ActiveWindow

  If TypeOf Win Is Outlook.Inspector Then
    Coll.Add Win.CurrentItem
  Else
    Set Sel = Win.Selection
    If Not Sel Is Nothing Then
      For i = 1 To Sel.Count
        Coll.Add Sel(i)
      Next
    End If
  End If
  Set GetCurrentItems = Coll
End Function
SAM SAM
Legen Sie fest, mit welcher "Identität" Ihre Emails beim Empfänger erscheinen sollen. Mit SAM bestimmen Sie den Absender und Speicherort für Emails anhand von Regeln.
email  Senden Sie eine Nachricht