Email automatisch kategorisieren

Mithilfe des Regelassistenten können Sie neuen E-Mails sofort beim Eintreffen Kategorien zuweisen. Das nützt Ihnen aber nichts, wenn Sie im Voraus noch nicht wissen, was damit geschehen soll.

Mit etwas VBA-Programmierung sind Sie flexibler: So können Sie z.B. immer dann eine Kategorie zuordnen, nachdem etwas in einen bestimmten Ordner verschoben wurde. Die Kategorie wird hier in der Konstante 'AUTO_CATEGORY' definiert, als Beispiel wird ein Unterordner des Posteingangs überwacht.

  So fügen Sie Makros in Outlook ein

Private WithEvents Items As Outlook.Items

'Diese Kategorie automatisch zuweisen
Private Const AUTO_CATEGORY As String = "(test)"

Private Sub Application_Startup()
  Dim Ns As Outlook.NameSpace
  Dim Inbox As Outlook.MAPIFolder
  Dim Subfolder As Outlook.MAPIFolder

  Set Ns = Application.GetNamespace("MAPI")

  'Posteingang
  Set Inbox = Ns.GetDefaultFolder(olFolderInbox)

  'Unterordner des Posteingangs
  Set Subfolder = Inbox.Folders("test")

  Set Items = Subfolder.Items
End Sub

Private Sub Items_ItemAdd(ByVal Item As Object)
  Dim Cats() As String
  Dim i&
  Dim Exists As Boolean

  If Len(Item.Categories) Then
    'Prüfe, ob die Kategorie schon zugewiesen ist
    Cats = Split(Item.Categories, ";")
    For i = 0 To UBound(Cats)
      If LCase$(Cats(i)) = LCase$(AUTO_CATEGORY) Then
        Exists = True
        Exit For
      End If
    Next

    If Exists = False Then
      Item.Categories = Item.Categories & ";" & AUTO_CATEGORY
      Item.Save
    End If

  Else
    Item.Categories = AUTO_CATEGORY
    Item.Save
  End If
End Sub