VBOffice

Adresse im CC-Feld suchen und verschieben

So suchen Sie eine (Teil)Adresse in der Empfängerliste einer Email. Bei einem Treffer wird die Email verschoben.

Zuletzt geändert: 23.11.2009 | Aufrufe: 47.525  | #79
◀ Vorheriges Beispiel Nächstes Beispiel ▶
ReplyAll ReplyAll
Mit diesem Addin für Outlook erhalten Sie in verschiedenen Situationen eine Warnung, bevor Sie auf eine Email versehentlich allen anderen Empfängern antworten.

Der Regel-Assistent in Outlook erlaubt nur, die eigene Adresse in CC zu suchen und die Mail dann zu verschieben. Mit diesem Beispiel können Sie eine beliebige Adresse (oder nur einen Teil davon) in CC suchen. Wenn der Begriff gefunden wird, wird die Mail in einen Unterordner des Posteingangs verschoben. Im Beispiel heißt der Ordner 'test'.


tip  So fügen Sie Makros in Outlook ein
Private WithEvents Items As Outlook.Items

Private Sub Application_Startup()
  Dim Ns As Outlook.NameSpace

  Set Ns = Application.GetNamespace("MAPI")
  Set Items = Ns.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub Items_ItemAdd(ByVal Item As Object)
  If TypeOf Item Is Outlook.MailItem Then
    MoveMessage Item
  End If
End Sub

Private Sub MoveMessage(Item As Outlook.MailItem)
  Dim Ns As Outlook.NameSpace
  Dim Recipients As Outlook.Recipients
  Dim Recip As Outlook.Recipient
  Dim Folder As Outlook.MAPIFolder
  Dim Find As String, FolderName As String

  Find = "info"
  FolderName = "test"

  Set Recipients = Item.Recipients
  For Each Recip In Recipients
    If Recip.Type = olCC Then
      If InStr(1, Recip.Address, Find, vbTextCompare) Then
        Set Ns = Application.GetNamespace("MAPI")
        Set Folder = Ns.GetDefaultFolder(olFolderInbox)
        Set Folder = Folder.Folders(FolderName)
        Item.Move Folder
        Exit For
      End If
    End If
  Next
End Sub
Category-Manager Category-Manager
Mit dem Category-Manager können Sie Outlook Kategorien gruppieren, synchronisieren und filtern, neuen Emails automatisch die Kategorie des Absenders zuweisen und vieles mehr. Das Addin ist auch für IMAP geeignet.
email  Senden Sie eine Nachricht